Artifact a648c16e2a1fa422c726f8e02a6b4ce5798e08ae

File user/crc/irc.retro part of check-in [daf59db064] - irc; rename 'ws' to 'token' by crc on 2010-06-17 17:34:01. [annotate]

( Rx to IRC Bindings ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ )
( Copyright [c] 2010, Charles Childers                        )
( License: ISC                                                )
( ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ )

&net open

( Data ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ )
create crlf 10 , 13 , 0 ,
variable socket

( Code ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ )
: send    ( $-  ) @socket net.send drop ;
: sendn   ( $-  ) send crlf send ;
: token   ( "-a ) 32 accept tib ;
: read    (  -c ) @socket net.recv ;
: pong    (  -  ) s" PONG :kornbluth.freenode.net" sendn ;

{{
  : r     (  -  )
    repeat read dup 10 = over 13 = or if; emit again ;
---reveal---
  : line  (  -  ) r r pong reset cr ;
  : lines ( n-  ) for line next ;
  : skim  ( "-  ) repeat key 27 = if; line again ;
}}

: say     ( "-  )
  s" PRIVMSG #retro :" send 27 accept tib sendn ;

: /server ( "-  )
  token 6667 net.socket dup !socket net.connect drop ;
: /nick   ( "-  )
  s" NICK " send token sendn ;
: /user   ( "-  )
  s" USER " send token send
  s"  8 *  : Charles Childers" sendn ;
: /join   ( "-  )
  s" JOIN " send token sendn ;

( Make Connection ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ )
/server kornbluth.freenode.net
/nick rx-irc
/user crc
/join #retro