Artifact d359f0894c18db96c25f8ab2d51ca705bf6c6271

File hangman/graphics.retro part of check-in [eca5386b7f] - Check in of hangman game from the forthlets part of the main Retro repo. by charleschilders on 2010-05-31 21:51:52. [annotate]

( ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ )
( Hangman for Retro Console                                    )
(  * Drawing routines.                                         )
( ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ )
( Copyright [c] 2010, Marc Simpson                             )
( License: ISC                                                 )
( ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ )

&console open
( --[ Drawing Routines ]-------------------------------------- )

: bar ( xyn- ) push at-xy pop for char: - emit next ;
: col ( xyn- ) for 2dup at-xy char: | emit 1+ next 2drop ;

( --[ Stages ]------------------------------------------------ )

( NOTE: 13 is FIXED unless we add more drawing XTs )

13 constant stages

here stages allot constant graphics
graphics variable: current-graphic

: current-graphic, current-graphic @ ! current-graphic ++ ;

here ] 20 15 15             bar ;   current-graphic,
here ] 20  5 10             col ;   current-graphic,
here ] 20  5 15             bar ;   current-graphic,
here ] 21  6 at-xy char: / emit ;   current-graphic,
here ] 30  6  2             col ;   current-graphic,
here ] 30  8 at-xy char: @ emit ;   current-graphic,
here ] 30  9  1             col ;   current-graphic,
here ] 29  9 at-xy char: / emit ;   current-graphic,
here ] 31  9 at-xy char: \ emit ;   current-graphic,
here ] 30  9  1             col ;   current-graphic,
here ] 30 10  1             col ;   current-graphic,
here ] 29 11 at-xy char: / emit ;   current-graphic,
here ] 31 11 at-xy char: \ emit ;   current-graphic,

( ============================================================ )